/*
	This C language subroutine computes the 
	addend of two floating point matricies.

		     
	z(i,j) = x(i,j) - y(i,j)
	
	
	The Run Time Library for the C Language.

	Gordon A. Sterling	(617) 461 - 3076
	DSP Development Tools Engineering

	Created on 5/25/90
	Updated on 5/94 by AS
	Updated on 1/95 by AS - separated polymorphic functions

	#include <matrix.h>					   <Header>
	float matadd(float z[][], float x[][], float y[][], int r, int s);<Prototype>
*/

#include "lib_glob.h"
#include "mat_glob.h"

.SEGMENT/CODE	Code_Space_Name;
.FILE 		RTL_FILENAME;

.GLOBAL		___mataddPDD;


___mataddPDD:	
add_core:	readparam4(R1);
	    	readparam5(R2);

pdd_add:	pm_ptr=R4;
		R0=R1-1, dm_bse=dma_i;		/*Test for vector*/
		R8=PASS R4, dma_i=R8;
		IF EQ R2=PASS R1, R1=R2;	/*If so, switch regs*/
		R1=R1-1, dm_ptr=R12;
		IF EQ JUMP (PC, pdd_one);	/*Single point! */
		LCNTR=R2, DO pdd_add_row UNTIL LCE;
			R2=DM(dma_i, dm_1);
			R4=DM(dm_ptr,dm_1);
			LCNTR=R1, DO pdd_add_col UNTIL LCE;
				F0=F2+F4, R2=DM(dma_i, dm_1);
pdd_add_col:			F0=F2+F4, R4=DM(dm_ptr, dm_1), PM(pm_ptr,pm_1)=R0;
			F0=F2+F4;
pdd_add_row:		PM(pm_ptr,pm_1)=R0;

pdd_done:	
		dma_i=dm_bse;

finish_up:	R0=PASS R8, FETCH_RETURN	/*Set ptr for return*/

restore_state:	RETURN (DB);
		RESTORE_STACK
		RESTORE_FRAME

pdd_one:	R2=DM(dma_i, dm_1);
		R4=DM(dm_ptr, dm_1);
		JUMP (PC, finish_up) (DB);
		F0=F2+F4, dma_i=dm_bse;
		PM(pm_ptr, pm_1)=R0;

.ENDSEG;