/*
	This C language subroutine computes the 
	addend of two floating point matricies.

		     
	z(i,j) = x(i,j) - y(i,j)
	
	
	The Run Time Library for the C Language.

	Gordon A. Sterling	(617) 461 - 3076
	DSP Development Tools Engineering

	Created on 5/25/90
	Updated on 5/94 by AS
	Updated on 1/95 by AS - separated polymorphic functions

	#include <matrix.h>				   <Header>
	float matadd(float z[][], float x[][], float y[][], int r, int s);<Prototype>
*/

#include "lib_glob.h"
#include "mat_glob.h"

.SEGMENT/CODE	Code_Space_Name;
.FILE 		RTL_FILENAME;

.GLOBAL	    	___mataddPDP;


___mataddPDP:	
add_core:	readparam4(R1);
	    	readparam5(R2);

pdp_add:	pm_bse=pma_i;
		R0=R1-1, dm_ptr=R8;		/*Test for vector*/
		R8=PASS R4, pm_ptr=R4;
		IF EQ R2=PASS R1, R1=R2;	/*If so, switch regs*/
		R1=R1-1, pma_i=R12;
		IF EQ JUMP (PC, pdp_one);	/*Single point!*/
		LCNTR=R2, DO pdp_add_row UNTIL LCE;
			R2=DM(dm_ptr, dm_1), R4=PM(pma_i,pm_1);
			LCNTR=R1, DO pdp_add_col UNTIL LCE;
				F0=F2+F4, R2=DM(dm_ptr, dm_1), R4=PM(pma_i, pm_1);
pdp_add_col:			F0=F2+F4, PM(pm_ptr,pm_1)=R0;
pdp_add_row:		PM(pm_ptr,pm_1)=R0;

pdp_done:	
		pma_i=pm_bse;			/* 24-bit DAG = 24-bit DAG->OK*/

finish_up:	R0=PASS R8, FETCH_RETURN	/*Set ptr for return*/

restore_state:	RETURN (DB);
		RESTORE_STACK
		RESTORE_FRAME

pdp_one:	R2=DM(dm_ptr, dm_1), R4=PM(pma_i, pm_1);
		JUMP (PC, finish_up) (DB);
		F0=F2+F4, pma_i=pm_bse;
		PM(pm_ptr, pm_1)=R0;

.ENDSEG;