/*
	This C language subroutine concatenates one
	string to another.

	The Run Time Library for the C Language.

	Gordon A. Sterling	(617) 461 - 3076
	DSP Development Tools Engineering

	Created on 4/30/90
	Updated on 5/94 by AS
	Updated on 3/95 by AS - separated polymorphic functions

	#include <string.h>				<Header>
	char *strcat(char *s1, const char *s2);		<Prototype>

*/

#include "lib_glob.h"
#include "str_glob.h"

.SEGMENT/CODE	Code_Space_Name;
.FILE 		RTL_FILENAME;

.GLOBAL	    ___strcatDP;

___strcatDP:		
cat_core:
pm_to_dm_cat:	dm_ptr=R4;			/*Point to output	*/
		R2=DM(dm_ptr,dm_1);	    	/*Rd 1st sample		*/
		R2=PASS R2, pm_ptr=R8;		/*Check for \0, Pt to input*/
		DO find_pm_dm_end UNTIL EQ;
		   IF NE R2=DM(dm_ptr,1);
		   IF NE R2=PASS R2;
		   IF NE R2=DM(dm_ptr,1);	/*Inc counter, read next*/
find_pm_dm_end:	   IF NE R2=PASS R2;		/*Check for \0		*/
		R2=PM(pm_ptr,1);		/*If input==NULL, no cat*/
		R2=PASS R2, MODIFY(dm_ptr, dm_M1);
		DO pm_dm UNTIL EQ;		/*Copy until \0*/
		   IF NE R2=PASS R2, DM(dm_ptr,1)=R2;
		   IF NE R2=PM(pm_ptr,1);
		   IF NE R2=PASS R2, DM(dm_ptr,1)=R2; /*Write to output	*/
pm_dm:		   IF NE R2=PM(pm_ptr,1);	/*Read sample		*/

restore_state:	R0=PASS R4, FETCH_RETURN
		RETURN (DB);
		RESTORE_STACK
                RESTORE_FRAME
.ENDSEG;